;:poke650,128:poke56,32:clr
;:sys36864
	*= $c000
	;.opt oo
tmp	=2
strout	=$ab1e
return	=$aad7
get	=65508
resp	=$fffc
vic	=$d000
axout	=$bdcd
save	=$ffd8
version	=65408
open	=$ffc0
setnam	=$ffbd
setpar	=$ffba
ga	=$ba
input	=$ffcf
close	=$ffc3
chkout	=$ffc9
chkin	=$ffc6
clrchn	=$ffcc
mode	=157
tmp2	=4
pg	=32
namlen	=$b7
keyl	=198
print	=$ffd2
run	lda #<hallo
	ldy #>hallo
	jsr strout
	lda #<xx2
	ldy #>xx2
	jsr strout
	ldx version
	lda #0
	sta mode
	jsr axout
	lda #6
	sta vic+33
		;sta vic+32
gk	jsr get
	cmp #"5"
	bne weiter
	jmp (resp)
weiter	bcs gk
	cmp #"1"
	bcc gk
	cmp #"3"
	bcs floppy
c64	sbc #"0"
	asl
	asl
	asl
	asl
	asl
	adc #160
	sta tmp+1
	ldy #0
	sty tmp
	sty tmp2
	ldx #32
	stx tmp2+1
copy	lda (tmp),y
	sta (tmp2),y
	iny
	bne copy
	inc tmp+1
	inc tmp2+1
	dex
	bne copy
	jmp safe
floppy	pha
	lda #<rumms
	ldy #>rumms
	jsr strout
	lda #15
	jsr close
	lda #15
	tay
	ldx #8
	jsr setpar
	lda #2
	ldx #<u9
	ldy #>u9
	jsr setnam
	jsr open
	lda #0
	sta tmp
	sta tmp2
	pla
	sec
	sbc #"3"
	asl
	asl
	asl
	asl
	asl
	adc #192
	sta tmp+1
	lda #32
	sta tmp2+1
	sta pages
page	lda tmp+1
	lsr
	lsr
	lsr
	lsr
	tax
	lda hexl,x
	jsr print
	lda tmp+1
	and #15
	tax
	lda hexl,x
	jsr print
	lda #"\x9d"
	jsr print
	jsr print
packen	ldx #15
	jsr chkout
	ldx #2
out15	lda mr,x
	jsr print
	dex
	bpl out15
	lda tmp
	jsr print
	lda tmp+1
	jsr print
	lda #pg
	jsr print
	jsr clrchn
d	ldx #15
	jsr chkin
	ldx #pg
	ldy #0
	stx bytes
hols	sty ymerk
	jsr get
	ldy ymerk
	sta (tmp2),y
	iny
	dec bytes
	bne hols
	jsr clrchn
	clc
	lda tmp2
	adc #pg
	sta tmp2
	lda tmp
	clc
	adc #pg
	sta tmp
	bne packen
	inc tmp2+1
	inc tmp+1
	dec pages
	bne page
safe	lda #15
	jsr close
	jsr getname
	bcs fini
	ldx #8
	stx ga
	ldx #0
	stx tmp
	ldy #64
	lda #32
	sta tmp+1
	lda #tmp
	jsr save
fini	lda #0
	sta namlen
	ldx #8
	lda #15
	tay
	jsr setpar
	jsr open
	ldx #15
	jsr chkin
	lda #<staat
	ldy #>staat
	jsr strout
loopin	jsr get
	jsr print
	cmp #13
	bne loopin
	jsr clrchn
	lda #15
	jsr close
	lda #<key
	ldy #>key
	jsr strout
	lda #0
	sta keyl
r	jsr get
	beq r
	cmp #" "
	bne norun
	jmp run
norun	cmp #13
	bne r
	jmp (resp)
pages	brk
bytes	brk
ymerk	brk
getname	lda #0
	sta keyl
	lda #<namein
	ldy #>namein
	jsr strout
	ldx #0
ggn	jsr input
	cmp #13
	beq fertn
	sta name,x
	inx
	cpx #16
	bcc ggn
fertn	txa
	beq abort
	ldx #<name
	ldy #>name
	jsr setnam
	lda #<ok
	ldy #>ok
	jsr strout
	clc
	rts
abort	jsr return
	sec
	rts
name	.word 0,0,0,0,0,0,0,0
hallo	.byte "\x93\x08\x0e\x05ROM - Klau V2.1     \x90von Nikolaus Heusler"
	.byt 13
	.byte "V1:nh-080788-arr"
	.byte " V2:nh-150589-arr \x05NSS'89"
	.byte "\x90\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4\xa4"
	.byte "\x11Welches ROM klauen ?"
	.byt 13
	.byte "\x90\x11 (1) Basic-ROM \x05 $a000-$bfff\x90"
	.byt 13
	.byte " (2) Kernal-ROM\x05 $e000-$ffff\x90"
	brk
xx2	.byt 13
	.byte " (3) Floppy-ROM\x05 $c000-$dfff\x90"
	.byt 13
	.byte " (4) Floppy-ROM\x05 $e000-$ffff\x90"
	.byt 13
	.byte " (5) Ende"
;".byt 13:.byte "qieses tility erzeugt auf iskette ein
;".byte " -faehiges e33 locks langes ile.
	.byt 13
	.byte "\x11C64 Kernal-Version: \x05"
	brk
ok	.byt 13
	.byte "\x11\x90ROM wird geklaut !\x11"
	brk
rumms	.byt 13
	.byte "\x11\x90Floppy-ROM wird in C64-RAM uebertragen"
	.byte "  Adresse: \x05$  xx\x9d\x9d\x9d\x9d"
	brk
hexl	.byte "0123456789abcdef"
namein	.byt 13
	.byte "\x11\x90Filename ? \x05"
	brk
u9	.byte "u9"
mr	.byte "r-m"
staat	.byt 13
	.byte "\x90Disk: \x05"
	brk
key	.byte "\x11\x05\x12RETURN\x92\x90 = Ende   \x05\x12SPACE\x92 \x90= Neustart"
	brk